home *** CD-ROM | disk | FTP | other *** search
/ Turnbull China Bikeride / Turnbull China Bikeride - Disc 2.iso / BARNET / FREENET / MELL / NETLIB00 / NetLib / s / gettime < prev    next >
Text File  |  1995-08-19  |  6KB  |  198 lines
  1. ; ----------------------------------------------------------------------
  2. ; Copyright Adam Goodfellow 1994, all rights reserved.
  3. ;
  4. ; Fast ARM code implementation of unix gettimeofday(2) function.
  5. ;
  6. ; C structures and function prototype:
  7. ;
  8. ; struct timeval {
  9. ;     long    tv_sec;        /* seconds */
  10. ;     long    tv_usec;    /* and microseconds */
  11. ; };
  12. ; 
  13. ; struct timezone {
  14. ;     int    tz_minuteswest;    /* minutes west of Greenwich */
  15. ;     int    tz_dsttime;    /* type of dst correction */
  16. ; };
  17. ;
  18. ; int gettimeofday(struct timeval *tv, struct timezone *tz);
  19. ;
  20.  
  21. IOC_Base    EQU    &3200000
  22. IOC_T0CountLow    EQU    &40
  23. IOC_T0CountHigh    EQU    &44
  24. IOC_T0LatchLow    EQU    &40
  25. IOC_T0LatchHigh    EQU    &44
  26. IOC_T0GoCommand    EQU    &48
  27. IOC_T0GetCount    EQU    &4C
  28.  
  29. XOS_EnterOS    EQU    &020016
  30. XOS_Word    EQU    &020007
  31.  
  32. r0        RN    0
  33. r1        RN    1
  34. r2        RN    2
  35. r3        RN    3
  36. r4        RN    4
  37. r5        RN    5
  38. r6        RN    6
  39. r7        RN    7
  40. r8        RN    8
  41. r9        RN    9
  42. r10        RN    10
  43. r11        RN    11
  44. r12        RN    12
  45. r13        RN    13
  46. r14        RN    14
  47. r15        RN    15
  48. sp        RN    13
  49. lr        RN    14
  50. pc        RN    15
  51. psr        RN    15
  52.  
  53. i_flag        EQU    &08000000
  54. svc_mode    EQU    &00000003
  55.  
  56.         AREA    |C$$code|,CODE,READONLY
  57.  
  58. r_s        RN    0    ;seconds
  59. r_u        RN    1    ;micro seconds
  60. r_a        RN    2    ;LS 32 bits of 40bit Risc OS time of day
  61. r_b        RN    3    ;MS 8 bits of 40bit Risc OS time of day
  62. r_c        RN    4    ;1/2 micro-secs read for IOC timer 0
  63. r_p        RN    5    ;Temp reg }
  64. r_t        RN    6    ;Temp reg } On of these is not needed
  65. r_v        RN    7    ;Temp reg }
  66. r_tv        RN    8    ;struct timeval *tv, or NULL
  67. r_tz        RN    9    ;struct timezone *tz, or NULL
  68.  
  69. ;Uses 8 bytes of stack for temp space
  70. ;    44 bytes for register storage.
  71. ;    could be reduced to 28 by fiddling temp regs and not saving r0-r3
  72. ;
  73.  
  74. ; -------------------------------------------------------------------------
  75. ; Read time of day and us from IOC timer 0
  76. ;
  77. ;On entry:
  78. ;  R0 = pointer to buffer for timeval struct
  79. ;  R1 = pointer to buffer for timezone struct
  80. ;
  81.             EXPORT    gettimeofday
  82. gettimeofday
  83.             STMFD    sp!, {r0-r9, lr}
  84.  
  85.             MOV    r_tz, r1
  86.             MOVS    r_tv, r0            ;timeval wanted?
  87.             BEQ    tod_tz                ;no - straight to timezone
  88.  
  89.             SUB    sp, sp, #8
  90.             MOV    r1, sp                ;Take SP here as wont be avilable later
  91.  
  92.             MOV    r_p, psr            ;Keep PSR from current processor mode
  93.             SWI    XOS_EnterOS
  94.             TEQP    psr, #(i_flag :OR: svc_mode)    ;Disable IRQs, stay in SVC mode
  95.  
  96.             MOV    r_a, #IOC_Base            ;Read IOC timer 0 value
  97.             STRB    r_a, [r_a, #IOC_T0GetCount]
  98.             LDRB    r_b, [r_a, #IOC_T0LatchLow]
  99.             LDRB    r_c, [r_a, #IOC_T0LatchHigh]
  100.             ORR    r_b, r_b, r_c, LSL #8
  101.             MOV    r_a, #&4e00            ;20000-n
  102.             ORR    r_a, r_a, #&20
  103.             SUB    r_b, r_a, r_b
  104.  
  105.             MOV    r0, #3                ;Get real time while IRQs still
  106.             STRB    r0, [r1, #0]            ;disabled to stop it ticking over
  107.             MOV    r0, #14                ;Returns 40 bit binary
  108.             SWI    XOS_Word
  109.  
  110.             TEQP    psr, r_p            ;Back to processor mode and IRQ state on entry
  111.             MOV    r_p, r_p
  112.  
  113.             LDMIA    sp!, {r_a, r_b}            ;t[4]...t[0] are bytes in r_a and r_b
  114.             AND    r_b, r_b, #&ff            ;Just want one byte from r_b
  115.  
  116. ; r_a, r_b = Real time,  r_c counter time (micro secs)
  117. ; ----------
  118.             LDR    r_v, =&6e996a00            ;To Unix and C time range
  119.             SUBS    r_a, r_a, r_v            ;5 byte time - 0x336e996a00
  120.             SBC    r_b, r_b, #&33            ;Risc OS time of 1st Jan 1970
  121.  
  122. ; ----------
  123. ; r_t is a temp,  r_v is a temp,  r_u is usecs,  r_s is secs
  124.  
  125. ; The following is a 40 bit div/mod by 100
  126.  
  127.             MOV    r_s, #0                ;tv->tv_sec = 0
  128.             MOV    r_u, #0                ;tv->tv_usec = 0
  129.  
  130.             MOV    r_t, r_b            ;t[4]
  131.             ORR    r_u, r_t, r_u, LSL #8        ;tv->tv_usec = (tv->tv_usec<<8) | t[4];
  132.             CMP    r_u, #100            ;if (tv->tv_usec>=100)
  133.             BLGE    divmod100            ;  tv->tv_usec = tv->tv_usec % 100;
  134.             ORRGE    r_s, r_t, r_s, LSL #8        ;  tv->tv_sec = (tv->tv_sec<<8) | (tv->tv_usec/100);
  135.  
  136.             MOV    r_t, r_a, LSR #24        ;t[3]
  137.             ORR    r_u, r_t, r_u, LSL #8        ;tv->tv_usec = (tv->tv_usec<<8) | t[4];
  138.             CMP    r_u, #100            ;if (tv->tv_usec>=100)
  139.             BLGE    divmod100            ;  tv->tv_usec = tv->tv_usec % 100;
  140.             ORRGE    r_s, r_t, r_s, LSL #8        ;  tv->tv_sec = (tv->tv_sec<<8) | (tv->tv_usec/100);
  141.  
  142.             MOV    r_t, r_a, LSR #16
  143.             AND    r_t, r_t, #&ff            ;t[2]
  144.             ORR    r_u, r_t, r_u, LSL #8        ;tv->tv_usec = (tv->tv_usec<<8) | t[4];
  145.             CMP    r_u, #100            ;if (tv->tv_usec>=100)
  146.             BLGE    divmod100            ;  tv->tv_usec = tv->tv_usec % 100;
  147.             ORRGE    r_s, r_t, r_s, LSL #8        ;  tv->tv_sec = (tv->tv_sec<<8) | (tv->tv_usec/100);
  148.  
  149.             MOV    r_t, r_a, LSR #8
  150.             AND    r_t, r_t, #&ff            ;t[1]
  151.             ORR    r_u, r_t, r_u, LSL #8        ;tv->tv_usec = (tv->tv_usec<<8) | t[4];
  152.             CMP    r_u, #100            ;if (tv->tv_usec>=100)
  153.             BLGE    divmod100            ;  tv->tv_usec = tv->tv_usec % 100;
  154.             ORRGE    r_s, r_t, r_s, LSL #8        ;  tv->tv_sec = (tv->tv_sec<<8) | (tv->tv_usec/100);
  155.  
  156.             MOV    r_t, r_a
  157.             AND    r_t, r_t, #&ff            ;t[0]
  158.             ORR    r_u, r_t, r_u, LSL #8        ;tv->tv_usec = (tv->tv_usec<<8) | t[4];
  159.             CMP    r_u, #100            ;if (tv->tv_usec>=100)
  160.             BLGE    divmod100            ;  tv->tv_usec = tv->tv_usec % 100;
  161.             ORRGE    r_s, r_t, r_s, LSL #8        ;  tv->tv_sec = (tv->tv_sec<<8) | (tv->tv_usec/100);
  162.  
  163.             RSB    r_t, r_u, r_u, LSL #7        ;cs x 10000 to get usecs
  164.             SUB    r_u, r_t, r_u, LSL #1
  165.             ADD    r_u, r_u, r_u, LSL #2
  166.             MOV    r_u, r_u, LSL #4
  167.  
  168.             ADD    r_u, r_u, r_c, LSR #1        ;Add in usecs/2 from IOC Timer
  169.  
  170.             STMIA    r_tv, {r_s, r_u}        ;Write to timeval struct
  171.  
  172. tod_tz            TEQ    r_tz, #0            ;Optionally write time zone (zero for now)
  173.             MOVNE    r_s, #0
  174.             MOVNE    r_u, #0
  175.             STMNEIA    r_tz, {r_s, r_u}
  176.  
  177.             LDMFD    sp!, {r0-r9, pc}^
  178.  
  179. ; ----------
  180. ; Highly optimised 16 bit div/mod 100
  181. ; could inline this with conditionals to give constant execution time.
  182. divmod100
  183.             MOV    r_v, r_u, LSR #1              ;Divide by 100 to get seconds
  184.             RSB    r_v, r_v, r_v, LSL #3
  185.             RSB    r_v, r_v, r_v, LSL #3
  186.             RSB    r_t, r_v, r_v, LSL #7
  187.             ADD    r_v, r_v, r_v, LSL #2
  188.             SUB    r_v, r_t, r_v, LSL #2
  189.             MOV    r_t, r_v, LSR #18        ;result in r_t
  190.  
  191.             ADD    r_v, r_t, r_t, LSL #2          ;Remainder of division (0-99)
  192.             ADD    r_v, r_v, r_v, LSL #2
  193.             SUB    r_u, r_u, r_v, LSL #2        ;remainder back in r_u
  194.  
  195.             MOVS    pc, lr
  196.  
  197.     END
  198.